【サンプルコード】VBAでクラスを使ったコードと使わないコードを比較する

クラスを使ったコードと使わないコードを比較する

関連書籍

クラスとは（クラスモジュールとは）

こちらの記事で説明しています。

クラスを用意する為の手順を解説VBA｜クラスとは何か｜本当に難しいのかを3つのポイントから検証

サンプルコード

任意の価格（動画では税抜価格1,000円）のものに対し税率10％、8％の税込価格が算出できるというツールです。

動画：サンプルコードのアウトプット

詳細は動画をご覧ください。（約2分です：BGMがありますので音にはご注意ください）

動画の補足説明

下のボタンはクラスを使わないコードが関連付けられたボタンです。どちらも同じことができます。

続いてクラスを使わないコードとクラスを使ったコードを紹介します。

クラスを使わないコード

最低でもコードの内容は理解してからクラス有のコードを見る流れにする為に先にクラス無のコードを出しました。

コード

Option Explicit
Sub 会計_クラス未使用()
'***************************************************************************************
'変数を定義
Dim product_value As Long '税抜価格
Dim tax_rate As Single '税率

Dim ws As Worksheet 'ワークシート
Set ws = ActiveSheet
'***************************************************************************************
'税抜価格の数値の有無や型を確認し変数product_valueに値をセットする
With ws
  If .Range("C4") = "" Or .Range("C4") = 0 Then
    MsgBox "セルC4に半角数値で税抜価格を設定してください", vbCritical, "セルC4を見直してください"
    Exit Sub
  Else
    If Not IsNumeric(.Range("C4")) Then
      MsgBox "セルC4に半角数値で税抜価格を設定してください", vbCritical, "セルC4を見直してください"
      Exit Sub
    Else
      'ここに落ちるとスルーして作業が進む
    End If
  End If
End With
product_value = Range("C4") 'セルから値を取得
'***************************************************************************************
'状況に応じて変数tax_rateに値をセットする
If MsgBox("店内飲食ですか?（税率10%）", vbYesNo + vbExclamation, "教えてください") = vbYes Then
  tax_rate = 0.1 '店内飲食
Else
  If MsgBox("持ち帰りですか?（税率8％)", vbYesNo + vbExclamation, "教えてください") = vbYes Then
    tax_rate = 0.08 '持ち帰り
  Else
    '指定無しの時はメッセージボックスで再度質問への回答を促す
    MsgBox "最初からやり直してください" & vbCrLf _
    & "（店内飲食か持ち帰りのどちらかを選択してください）", vbCritical
    Exit Sub
  End If
End If
'***************************************************************************************
'各種結果を計算してメッセージボックスとして表示
MsgBox "税率" & tax_rate * 100 & "%で計算" & vbCrLf & vbCrLf _
& "税込価格：" & FormatCurrency(product_value * (1 + tax_rate)) & vbCrLf & vbCrLf _
& "商品価格：" & FormatCurrency(product_value) & vbCrLf & vbCrLf _
& "税金：" & FormatCurrency(product_value * tax_rate), vbInformation, "お知らせ"
'***************************************************************************************
End Sub

クラスを使ったコード

ワークシートとVBAProject

メッセージボックスの表示に従って操作を進めると税込価格などが表示されます。

コード

コードを貼り付ける場所は3箇所です。

標準モジュール（Module1）のコードです。

Sub 会計_クラス使用()

Dim myC As Check 'クラスを定義する
Set myC = New Check 'クラスをインスタンス化

myC.check_please

End Sub

Checkクラスのコードです。

Public Sub check_please()

Dim myP As Price 'クラスを定義する
Set myP = New Price 'クラスをインスタンス化

With myP
  'Priceクラスで各種値を用意する
  .initialize
  
  If .calc_tax = 0 Then
      Exit Sub
  Else
    'Priceクラスから必要な値を取り出してメッセージボックスに表示させる
      MsgBox "税率" & .calc_tax & "%で計算" & vbCrLf & vbCrLf _
      & "税込価格：" & FormatCurrency(.tax_include) & vbCrLf & vbCrLf _
      & "商品価格：" & FormatCurrency(.product_value) & vbCrLf & vbCrLf _
      & "税金：" & FormatCurrency(.tax_only), vbInformation, "お知らせ"
  End If
End With

End Sub

Priceクラスのコードです。

Private wst As Worksheet
Private rte As Single
Private val As Long

Public Property Let input_ws(ByVal new_ws As Worksheet)
If wst Is Nothing Then
  Set wst = new_ws 'ワークシートを設定
'Else
  'MsgBox "シートは既に設定されているので変更しません", vbCritical
End If
End Property

Public Property Let input_tax(ByVal new_tax As String)
If rte = 0 Then
  rte = new_tax
'Else
  'MsgBox "税率は既に決まっているので変更しません", vbCritical
End If
End Property

Public Property Let input_value(ByVal new_value As Variant)
'製品価格
If IsNumeric(wst.Range("C4")) Then
  If val = 0 Then
    val = new_value
  'Else
    'MsgBox "税抜価格は既に決まっているので変更しません", vbCritical
  End If
Else
  '半角数値じゃなかったらスルー
End If
End Property

Public Property Get product_value() As Long
'製品価格
product_value = val
End Property

Public Property Get tax_include() As Currency
'税込価格を算出
tax_include = val * (1 + rte)
End Property

Public Property Get tax_only() As Currency
'税金のみを算出
tax_only = val * rte
End Property

Public Property Get calc_tax() As Currency
'税金の表示を確定させる（パーセント表示にする）
calc_tax = rte * 100
End Property

Public Sub initialize()

input_ws = ActiveSheet 'ボタンが用意されたシートを変数wsにセット
input_value = wst.Range("C4") 'セルC4の値を変数input_valueにセットする

If val = 0 Then
  MsgBox "セルC4に半角数値で税抜価格を設定してください", vbCritical, "セルC4を見直してください"
  Exit Sub
Else
  '値が入っていれば次の処理に進む
End If

If MsgBox("店内飲食ですか?（税率10%）", vbYesNo + vbExclamation, "教えてください") = vbYes Then
    input_tax = 0.1
Else
  If MsgBox("持ち帰りですか?（税率8％)", vbYesNo + vbExclamation, "教えてください") = vbYes Then
    input_tax = 0.08
  Else
    '指定無しの時はメッセージボックスで再度質問への回答を促す
    MsgBox "最初からやり直してください" & vbCrLf _
    & "（店内飲食か持ち帰りのどちらかを選択してください）", vbCritical
    Exit Sub
  End If
End If

End Sub

解説

この記事内で全部を説明するのは難しいです。よってここでは勉強する為のポイントを提示します。

1_「どんな構造でクラスを用意するのか」の考え方

2_クラスを用意する方法（Newの使い方）

こちらの記事で解説しています。

クラスを用意する為の手順を解説VBA｜クラスとは何か｜本当に難しいのかを3つのポイントから検証

3_クラスの中でプロパティとメソッドを用意する方法

2番と同様の記事で一部を紹介しています。

4_クラス内にPrivateで変数を用意する方法

5_クラスの中にクラスを用意する方法

6_Property Let、Property Get

まとめ

EnjoyExcel