エクセルマクロでモジュールを分ける時の考え方共通作業は切り離そう

Sub 抽出用()
 
'変数の定義
Dim 行 As Long
Dim 列 As Long
Dim 抽出行 As Long
 
'画面更新の停止
Application.ScreenUpdating = False
 
'データベースの最終行と最終列を確認する
 With Sheet1
  行 = .Cells(Rows.Count, 1).End(xlUp).Row
  列 = .Cells(5, Columns.Count).End(xlToLeft).Column
 End With
 
'抽出シートの４列目をループする
For 抽出行 = 6 To Cells(Rows.Count, 4).End(xlUp).Row
 
 '抽出シートの名前がデータベースに居るのか確認。
 If WorksheetFunction.CountIf(Sheet1.Range(Sheet1.Cells(6, 1), Sheet1.Cells(行, 1)), Sheet2.Cells(抽出行, 4)) > 0 Then
  
  '居たらVLOOKUPで結果を抽出
  Cells(抽出行, 5) = WorksheetFunction.vlookup(Sheet2.Cells(抽出行, 4), Sheet1.Range(Sheet1.Cells(6, 1), Sheet1.Cells(行, 列)), 8, False)
  Cells(抽出行, 6) = WorksheetFunction.vlookup(Sheet2.Cells(抽出行, 4), Sheet1.Range(Sheet1.Cells(6, 1), Sheet1.Cells(行, 列)), 10, False)
  
 Else
  '居ない時は「該当なし」と表示させる
  Cells(抽出行, 5) = "該当なし"
  Cells(抽出行, 6) = "該当なし"
  
 End If
  
Next
'画面更新停止の解除
Application.ScreenUpdating = True
End Sub

Sub 削除用()
 
'変数の定義
Dim 行 As Long
Dim 行2 As Long
 
'抽出シートの都道府県とカレーの食べ方が入力されている列の最終行を認識
行 = Cells(Rows.Count, 5).End(xlUp).Row
行2 = Cells(Rows.Count, 6).End(xlUp).Row
 
'抽出シートの都道府県とカレーの食べ方が入力されている列の最終行が５より大きかったら・・・
If 行>5 and 行2>5 then
 
'結果をクリアにする（都道府県とカレー食べ方の抽出結果を消去する）
 Range(Cells(6, 5), Cells(行, 6)).ClearContents
 
End If
 
End Sub

Private Sub CommandButton1_Click()

'ここではオブジェクトとプロパティの値を取得して
'メイン作業のプロシージャに値を引き渡す為の準備をするためのコード

'************************************************************
'変数の定義
Dim clm1 As Integer 'VLOOKUP関数で取得する1つ目の列を指定する変数
Dim clm2 As Integer  'VLOOKUP関数で取得する2つ目の列を指定する変数
Dim sht As Worksheet '実行ボタンのあるワークシートへの参照を収納する変数
'************************************************************

'画面更新の停止
Application.ScreenUpdating = False

'************************************************************
clm1 = 8
clm2 = 10
Set sht = Sheet2

'作業をする為のプロシージャにお願いする
Call メイン作業(clm1, clm2, sht)
'************************************************************

'画面更新停止の解除
Application.ScreenUpdating = True

End Sub

Public Sub メイン作業(ByRef c1 As Integer, ByRef c2 As Integer, ByRef ws As Worksheet)

'DBから抽出する際の列番号と値を出力する為のワークシートの情報を引数として取得
'もとのコードからの引数は値を書き換えるものではないのでByRefでもByValでも可

'引数c1、c2を使ってVLOOKUP関数を実行し値をオブジェクト変数wsのシートに返す
'最後に引数wsの参照を開放するがその後に作業は無いので実質無でもOK。

'************************************************************
'変数の定義
Dim name_r As Long '抽出シートのD列を周回する為の変数
Dim r As Long  'データベースの最終行の値を格納する為の変数
Dim c As Long  'データベースの最終列を格納する為の変数
'************************************************************
'データベースの最終行と最終列を確認する
With Sheet1
    r = .Cells(Rows.Count, 1).End(xlUp).Row
    c = .Cells(5, Columns.Count).End(xlToLeft).Column
End With
'************************************************************
'表題を取得しオブジェクト変数wsのシートに記入する
ws.Range("E5") = Sheet1.Cells(5, c1)
ws.Range("F5") = Sheet1.Cells(5, c2)
'************************************************************
'抽出シートの４列目をループする
For name_r = 6 To ws.Cells(Rows.Count, 4).End(xlUp).Row

    'オブジェクト変数wsの4列目にいる名前がデータベースに居るのか確認
    If WorksheetFunction.CountIf(Sheet1.Range(Sheet1.Cells(6, 1), Sheet1.Cells(r, 1)), ws.Cells(name_r, 4)) > 0 Then
     
      '居たらVLOOKUPで結果を抽出
        ws.Cells(name_r, 5) = WorksheetFunction.vlookup(ws.Cells(name_r, 4), Sheet1.Range(Sheet1.Cells(6, 1), Sheet1.Cells(r, c)), c1, False)
        ws.Cells(name_r, 6) = WorksheetFunction.vlookup(ws.Cells(name_r, 4), Sheet1.Range(Sheet1.Cells(6, 1), Sheet1.Cells(r, c)), c2, False)
    
    Else
      '居ない時は「該当なし」と表示させる
        ws.Cells(name_r, 5) = "該当なし"
        ws.Cells(name_r, 6) = "該当なし"

    End If

Next
'************************************************************
'オブジェクト変数wsの開放
Set ws = Nothing

End Sub